Aufgabe A4.2 Ressourcen- und Arbeitsplanoptimierung
# Modell
set STAT;
set PROD;
set ROUT {PROD};
param wkmr {k in PROD, m in STAT, r in ROUT[k]} >= 0;
param Alpha {PROD} >= 0;
param FixKosten {STAT} >= 0;
param VarKosten {k in PROD, r in ROUT[k]} >= 0;
param Xmin >= 0;
var X {k in PROD, r in ROUT[k]} >= 0;
var Server {STAT} >= 0 integer;
minimize Ziel_Funktion:
sum {k in PROD, r in ROUT[k]} VarKosten [k,r] * X[k,r]
+ sum {m in STAT} FixKosten[m] * Server[m];
subject to Kapazitaet {m in STAT}:
sum {k in PROD, r in ROUT[k]} X[k,r]*wkmr[k,m,r] <= Server[m];
subject to Aufteilung {k in PROD}:
sum {r in ROUT[k]} X[k,r] = Alpha[k] *
sum {l in PROD, r in ROUT[l]} X[l,r];
subject to Gesamt_Produktion:
sum {k in PROD, r in ROUT[k]} X[k,r] >= Xmin;
#Daten
set STAT := 1 2 3 4 5 6 ;
set PROD := 1 2 ;
set ROUT[1] := 1 2 ;
set ROUT[2] := 3 4 5 ;
param FixKosten := 1 200 2 2000 3 1800 4 1300 5 1500 6 150 ;
param VarKosten :=
[1,*] :=
1 0
2 0
[2,*] :=
3 0
4 0
5 0;
param Alpha := 1 0.50 2 0.50;
param wkmr :=
[1,*,*]: 1 2 :=
1 10 10
2 15 10
3 10 0
4 0 10
5 10 0
6 8 6
[2,*,*]: 3 4 5 :=
1 5 5 5
2 5 6 4
3 6 5 12
4 0 10 8
5 10 0 2
6 8 8 10;
param Xmin := 0.4;