Aufgabe A1.6 Standortplanung
# Modell
# Standortwahl mit Größenklassen
param S >0; # Menge der Standorte
param DEST >0; # Nachfrageorte
param R >0; # Anzahl Größenklassen
var gamma {1..S, 1..R} binary; # binaere Zuordnungsvariable
var q {1..S, 1..R} >=0; # Produktionsmenge
var trans {1..S, 1..DEST} >=0; # Transportmenge
param f {1..S, 1..R} >=0; # Fixkosten
param c {1..S, 1..DEST} >=0; # Transportkosten
param g {1..S, 0..R} >=0; # Obergrenze der Größenklasse
param d {1..DEST} >=0; # Bedarf
minimize Kosten:
sum {s in 1..S, r in 1..R} (f[s,r] * gamma[s,r])
+ sum {s in 1..S, j in 1..DEST} (c[s,j] * trans[s,j]);
subject to Bedarfsdeckung {j in 1..DEST}:
sum {s in 1..S} trans[s,j] = d[j];
subject to Gesamtmengen {s in 1..S}:
sum {j in 1..DEST} trans[s,j] = sum {r in 1..R} q[s,r];
subject to Kapazitäts_Obergrenze {s in 1..S, r in 1..R}:
q[s,r] <= g[s,r] * gamma[s,r];
subject to Kapazitäts_Untergrenze {s in 1..S, r in 2..R}:
q[s,r] >= (g[s,r-1]+1)*gamma[s,r];
subject to Selektion {s in 1..S}:
sum {r in 1..R} gamma[s,r] <= 1;