Aufgabe A1.5 Standortplanung
# Modell
# Standortmodell (single-sourcing)
set ORIG; # potentielle Standorte
set DEST; # Abnehmerzentren
param supply {ORIG} >= 0; # Kapazitäten
param demand {DEST} >= 0; # Bedarfsmengen
param vcost {ORIG,DEST} >= 0; # variable Transportkosten
param fcost {ORIG} >= 0; # Fixkosten
var Trans {ORIG,DEST} >= 0; # Transportmengen
var Gam {ORIG} binary; # Standortvariable (0 oder 1)
var X {ORIG, DEST} binary; # Zuordnungsvariable (0 oder 1)
minimize total_cost:
sum {i in ORIG, j in DEST} vcost[i,j] * Trans[i,j]
+ sum {i in ORIG} fcost[i] * Gam[i];
subject to Supply {i in ORIG}:
sum {j in DEST} Trans[i,j] <= supply[i] * Gam[i];
subject to Demand {i in ORIG, j in DEST}:
Trans[i,j] = demand[j] * X[i,j] ;
subject to SingleSource {j in DEST}:
sum {i in ORIG} X[i,j] = 1;
# Daten
set ORIG := DO HB KA PA WU N;
set DEST := HH B M K F KS;
param supply := DO 100 HB 200 KA 200 PA 200 WU 200 N 200;
param demand := HH 100 B 90 M 110 K 120 F 50 KS 40;
param fcost := DO 15000 HB 20000 KA 20000 PA 20000 WU 20000 N 20000;
param vcost : HH B M K F KS:=
DO 342 500 612 94 219 165
HB 119 390 745 324 467 281
KA 631 687 277 313 145 323
PA 827 639 195 630 443 489
WU 526 470 273 325 116 223
N 607 431 162 432 223 304;